De ESP8266-12(e) als monitoring device

De afgelopen periode ben ik druk bezig geweest met verschillende zaken.

Eén van die zaken was het monitoren van de ruimten op ons perceel. Op ons perceel staat uiteraard een huis en een schuur. In de schuur wil ook nog wel eens de lamp blijven branden. Vanuit ons huis hebben we daar namelijk geen zicht op. Dus ook een plek om te monitoren.

Door gebruik te maken van de ESP8266 is het mogelijk om gegevens over en weer te verzenden via wifi van en naar de sensor-pc. Deze pc verzamelt alle gegevens in het hele huis en gaat hier eventueel mee aan de slag.

Wat moet het monitoring device kunnen

Het monitoring device moet het volgende kunnen

1. temperatuur meten
2. licht  meten (lamp aan of uit)
3. deze gegevens verzenden via wifi
4. Eventueel ontvangst van opdrachten om lampen uit te doen e.d.
5. aan en uit kunnen gaan om zo batterij te besparen

Wat moet de sensor-pc kunnen

1. data verzamelen van het hele huis
2. data opslaan in database
3. data kunnen oproepen in verschillende rapporten
4. huidige situatie tonen op een scherm

Al met al dus heel wat om te doen, maar nu terug naar de esp8266 als monitoring device

ESP8266-12e Pinout en omschrijving

De ESP8266 -12 is een device wat veel verschillende poorten heeft.

Het is dus zo te zien een erg veelzijdig apparaatje. Hierdoor zijn er ook verschillende mogelijkheden.

Er zijn 11 GPIO-poorten waarvan de RX en de TX ook nog kunnen worden ingezet als GPIO poort. Dus in totaal 13 beschikbare poorten voor digitale in-/output.

Er is 1 ADC poort aanwezig voor het meten van analoge signalen zoals voltage enzovoorts.

Door middel van de SCLK, MOSI, MISO en CS is deze ook te gebruiken voor SPI communicatie wat hier te ver voert om uit te leggen. Daar hebben ze al mooie documenten voor gemaakt.

In mijn project maak ik voor de meetingen gebruik van de volgende poorten:

• GPIO5
• GPIO4
• GPIO0
• GPIO2
• GPIO15
• GND
• RST
• CP_PD
• GPIO16
• GPIO12
• VCC

Al met al, dus een hele boel poorten die worden gebruikt.

Hier een beschrijving waarvoor ze dan worden gebruikt

Voor het normale gebruik van de ESP8266-12E heb ik de volgende connecties al in gebruik. Dit zal waarschijnlijk wel iets minder kunnen zijn, maar het werkt naar behoren:

Hiernaast heb ik nog de volgende aansluitingen er bij zitten

• GPIO5 heeft een koppeling naar de DS18B20 pen 1. Dit is namelijk de aansluiting die op een bepaald moment hoog wordt gezet om de DS18B20 uit te lezen.

• GPIO12 meetpin voor de LDR
• GPIO16 gekoppeld met de RST

In het volgende schema is te zien hoe de aansluitingen zitten

Ik heb een beetje met kleuren gewerkt om het wat duidelijker te maken voor mezelf.

deep sleep mode ESP8266

Tot mijn verbazing heeft de ESP8266 een deep sleep mode. Dit is erg handig als je de ESP8266 op batterijen (3xAA) wilt laten lopen. Dan kan er niet teveel stroom worden gebruikt.

Nu wil het voordeel dat er geen LEDje brand op de print van de ESP8266, waardoor er daarmee ook geen stroom wordt gebruikt 🙂

Om de deep sleep mode te activeren dienen de volgende regels te worden toegevoegd in de sketch (ik maak gebruik van de Arduino IDE):

onder de #includes :

extern "C" {
#include "user_interface.h" //for sleep
}

In de loop heb ik de volgende regels opgenomen

  Serial.println();
  Serial.println("going into sleep....");
  delay(1000);
  system_deep_sleep_set_option(0);
  system_deep_sleep(5*60*1000000); //5 min

Om dit werkend te krijgen dient er ook nog een aanpassing te gebeuren op de print.

GPIO16 moet worden doorverbonden met de RST. En dat is alles

Om er voor te zorgen, dat er ook geen constante stroom staat op de DS18B20 en de LDR, maak ik gebruik van GPIO5 die hoog of laag wordt gezet afhankelijk van het wel of niet meten van de gegevens. Hierdoor bespaar ik weer wat mA’s 🙂

  system_deep_sleep(5*60*1000000); //5 min

De regel hierboven bepaald hoelang de ESP in de deep_sleep mode zit. In dit geval 5 minuten

Zoals te zien is, is er nog veel in te stellen, en waarschijnlijk kan ik ook nog een andere communicatie methode kiezen om nog meer mA’s te besparen, maar dat gaat me even te ver. Ik ben al lang blij dat het allemaal werkt.

Hieronder de ino die ik heb geschreven. Het is af en toe bagger, maar het werkt naar behoren

Sensor_module_ezp8266-12

#include <ESP8266WiFi.h>
#include <WiFiClient.h>
#include <ESP8266WebServer.h>
#include <ESP8266mDNS.h>
#include <OneWire.h>
#include <DallasTemperature.h>
extern "C" {
#include "user_interface.h" //for sleep
}


const char* ssid = "Ziggo8BF1A8";
const char* password = "9BW9FGFQE4JY";
MDNSResponder mdns;

ESP8266WebServer server(80);
const char* host = "192.168.2.14";

#define ONE_WIRE_BUS 4  // on pin 4 (a 4.7K resistor is necessary) 
OneWire ds(4);
const int ldr = 12;      //init ldr
int ProviderPin=5;    //to provide voltage

float RoomTemp;          //temperature from sensor(0)
int LdrValue;            //high or low ldr
String WebString = "";
int kamer=1;

// Setup a oneWire instance to communicate with any OneWire devices
// (not just Maxim/Dallas temperature ICs)
OneWire oneWire(ONE_WIRE_BUS);
// Pass our oneWire reference to Dallas Temperature.
DallasTemperature sensors(&oneWire);

void handleRoot() {
  LdrValue = digitalRead(ldr);
  WebString = "Temperatuur is: " + String((int)RoomTemp) + "*C";
  WebString += "\n\rVerlichting is: ";
  WebString += digitalRead(ldr);
  server.send(200, "text/plain", WebString);
}

void handleNotFound() {
  String message = "File Not Found\n\n";
  message += "URI: ";
  message += server.uri();
  message += "\nMethod: ";
  message += (server.method() == HTTP_GET) ? "GET" : "POST";
  message += "\nArguments: ";
  message += server.args();
  message += "\n";
  for (uint8_t i = 0; i < server.args(); i++) {
    message += " " + server.argName(i) + ": " + server.arg(i) + "\n";
  }
  server.send(404, "text/plain", message);
}

void setup(void) {
  
  pinMode(ldr, INPUT);
  // prepare GPIO5 for providing power to ldr and ds18b20
  pinMode(ProviderPin, OUTPUT);
  digitalWrite(ProviderPin, LOW);

  Serial.begin(115200);
  WiFi.begin(ssid, password);
  Serial.println("");
  digitalWrite(ProviderPin, HIGH);  //provide power to ldr and ds18b20
  delay (1000);
    ds.reset();  
  sensors.begin();
  // Wait for connection
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
  Serial.print(".");
  }
  Serial.println("");
  Serial.print("Connected to ");
  Serial.println(ssid);
  Serial.print("IP address: ");
  Serial.println(WiFi.localIP());

  if (mdns.begin("esp8266", WiFi.localIP())) {
    Serial.println("MDNS responder started");
  }

  server.on("/", handleRoot);

  server.on("/inline", []() {
    server.send(200, "text/plain", "this works as well");
  });

  server.onNotFound(handleNotFound);

  server.begin();
  Serial.println("HTTP server started");
  // Start up the library

}


void CheckTemp() {
  // call sensors.requestTemperatures() to issue a global temperature
  // request to all devices on the bus


  sensors.requestTemperatures(); // Send the command to get temperatures

  Serial.print("Temperature for Device 1 is: ");
  Serial.print(sensors.getTempCByIndex(0));
  RoomTemp = sensors.getTempCByIndex(0);
  // Why "byIndex"?
  // You can have more than one IC on the same bus.
  // 0 refers to the first IC on the wire
  LdrValue = digitalRead(ldr);
  Serial.print("|  LDR is: ");
  Serial.println(LdrValue);
  delay (1000);
  digitalWrite(ProviderPin, LOW);  //disconnect power from ldr and ds18b20
}

void WriteDatabase() {
  Serial.println("Wake up....");
  Serial.println();
  Serial.print("connecting to ");
  Serial.println(host);

  // Use WiFiClient class to create TCP connections
  WiFiClient client;
  const int httpPort = 80;


  if (!client.connect(host, httpPort)) {
    Serial.println("connection failed");
    return;
  }


  client.print("GET /rooms.php?roomnr=");
  client.print(kamer);
  client.print("&roomtemp=");
  client.print(RoomTemp);
  client.print("&roomlight=");
  client.print(LdrValue);
  client.println(" HTTP/1.1");
  client.println("Host: 192.168.2.14");
  client.println("User-Agent: arduino-ethernet");
  client.println("Connection: close");
  client.println();


}

void loop(void) {
  delay(1000);
  CheckTemp();
  server.handleClient();
  WriteDatabase();
  Serial.println();
  Serial.println("going into sleep....");
  delay(1000);
  system_deep_sleep_set_option(0);
  system_deep_sleep(5*60*1000000); //5 min
}